Hogyan emelhetünk ki egy cellán belül egy adott szöveget más szöveg alapján?

Az Excel programban könnyen lehet, hogy kiemeljük a cellákat egy adott szöveg alapján, de itt szeretnék kiemelni egy cellán belül egy konkrét szöveget, hogy az kiemelkedő legyen, de a teljes cellát nem. Ez talán a legtöbbünk számára problémás. Ebben a cikkben néhány trükköt fogok beszélni ennek a feladatnak az Excelben történő megoldására.

Jelöljön ki egy vagy több specifikus szöveget több cellában VBA kóddal

Jelöljön ki egy vagy több konkrét szöveget több cellában egy csodálatos funkcióval

Jelöljön ki egy cellán belül egy adott szöveget más, VBA kóddal ellátott szöveg alapján

Jelöljön ki egy vagy több specifikus szöveget több cellában VBA kóddal

Például van egy sor szöveges karakterláncom, és most szeretném kiemelni a konkrét szöveget “Ég”Ezekben a cellákban az eredmény eléréséhez a következő képernyőképek szerint:

A cellában a szöveg csak egy részének kiemeléséhez a következő VBA-kód segíthet.

1. Jelölje ki azokat a cellákat, amelyekkel ki szeretné emelni az adott szöveget, majd tartsa lenyomva a gombot ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

2. Kattints betétlap > Modulok, és illessze be a következő kódot a Modulok Ablak.

VBA kód: Jelölje ki a szöveg egy részét egy cellában:

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
cFnd = InputBox("Enter the text string to highlight")
y = Len(cFnd)
For Each Rng In Selection
  With Rng
    m = UBound(Split(Rng.Value, cFnd))
    If m > 0 Then
      xTmp = ""
      For x = 0 To m - 1
        xTmp = xTmp & Split(Rng.Value, cFnd)(x)
        .Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
        xTmp = xTmp & cFnd
      Next
    End If
  End With
Next Rng
Application.ScreenUpdating = True
End Sub

3. Ezután nyomja meg a gombot F5 kulcs a kód futtatásához, és megjelenik egy felszólító mező, amely emlékezteti Önt a csak kiemelni kívánt szöveg beírására, lásd a képernyőképet:

4. Kattintson a gombra OK gombra, az összes megadott szöveget csak a cellák jelölték ki, lásd a képernyőképet:

tippek: Ha több kulcsszót kell kiemelnie a szöveges karakterláncokból, kérjük, alkalmazza az alábbi kódot:
VBA-kód: Jelöljön ki több kulcsszót a szöveges karakterláncokból:

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
Dim xFNum As Integer
Dim xArrFnd As Variant
Dim xStr As String
cFnd = InputBox("Please enter the text, separate them by comma:")
If Len(cFnd) < 1 Then Exit Sub
xArrFnd = Split(cFnd, ",")
For Each Rng In Selection
With Rng
For xFNum = 0 To UBound(xArrFnd)
xStr = xArrFnd(xFNum)
y = Len(xStr)
m = UBound(Split(Rng.Value, xStr))
If m > 0 Then
xTmp = ""
For x = 0 To m - 1
xTmp = xTmp & Split(Rng.Value, xStr)(x)
.Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
xTmp = xTmp & xStr
Next
End If
Next xFNum
End With
Next Rng
Application.ScreenUpdating = True
End Sub

Ezután a felbukkanó mezőbe írja be a kiemelni kívánt kulcsszavakat (vesszővel válassza el a szavakat), lásd a képernyőképet:

Ezután kattintson OK gombra, a megadott szavakat egyszerre emelte ki, lásd a képernyőképeket:

Megjegyzések: A fenti kódok megkülönböztetik a kis- és nagybetűket.

Jelöljön ki egy vagy több konkrét szöveget több cellában egy csodálatos funkcióval

Ha nem ismeri az Excel kódját, itt bemutatok egy egyszerű eszközt - Kutools az Excel számára, Annak Jelölje meg a kulcsszót funkcióval egyszerre kiemelheti a cellákon belül az adott egy vagy több kulcsszót.

Telepítése után Kutools az Excel számára, kérjük, tegye a következőket:

1. Kattints Kutools > szöveg > Jelölje meg a kulcsszót, lásd a képernyőképet:

2. Az Jelölje meg a kulcsszót párbeszédpanelen tegye a következőket:

• Válassza ki a használni kívánt adattartományt a Választék szövegdoboz;
• Jelölje ki azokat a cellákat, amelyek a kiemelni kívánt kulcsszavakat tartalmazzák, a kulcsszavakat manuálisan is megadhatja (vesszővel elválasztva) Kulcsszó szövegdoboz
• Végül meg kell adnia egy betűszínt a szövegek ellenőrzéssel történő kiemeléséhez Jelölje meg a kulcsszó színeit választási lehetőség. (A kulcsszavakat tartalmazó teljes cellák színezéséhez válassza a ikont Jelölje meg a cellatartalom színeit választási lehetőség)

3. Ezután kattints a gombra Ok gombra, az összes megadott szöveget kiemelte az alábbi képernyőkép:

Megjegyzések: Ez a funkció nem különbözteti meg a kis- és nagybetűket. Ha a kis- és nagybetűket szeretné kiemelni, ellenőrizze Match Case a Jelölje meg a kulcsszót párbeszédablak.

Jelöljön ki egy cellán belül egy adott szöveget más, VBA kóddal ellátott szöveg alapján

Itt van egy másik helyzet, két oszlopom van, amelyek közül az első oszlop tartalmazza a szöveges karakterláncokat, a második pedig a konkrét szöveget, most ki kell emelnem az első oszlopban a relatív szöveget a második oszlopban szereplő szöveg alapján. sor.

1. Tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

2. Kattints betétlap > Modulok, és illessze be a következő kódot a Modulok Ablak.

VBA kód: Jelölje ki a szöveg egy részét egy cellában más szöveg alapján:

Sub highlight()
'Updateby Extendoffice
    Dim xStr As String
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    Dim xChar As String
    Dim I As Long
    Dim J As Long
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
LInput:
    Set xRg = Application.InputBox("please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    If xRg.Areas.Count > 1 Then
        MsgBox "not support multiple columns"
        GoTo LInput
    End If
    If xRg.Columns.Count <> 2 Then
        MsgBox "the selected range can only contain two columns "
        GoTo LInput
    End If
    For I = 0 To xRg.Rows.Count - 1
        xStr = xRg.Range("B1").Offset(I, 0).Value
        With xRg.Range("A1").Offset(I, 0)
            .Font.ColorIndex = 1
            For J = 1 To Len(.Text)
                If Mid(.Text, J, Len(xStr)) = xStr Then .Characters(J, Len(xStr)).Font.ColorIndex = 3
            Next
        End With
    Next I
End Sub

3. A kód beillesztése után nyomja meg a gombot F5 kulcs a futtatásához, megjelenik egy prompt doboz, amely emlékezteti Önt arra, hogy válassza ki az adattartományt, amely tartalmazza mind a szöveges karakterláncot, mind pedig a kiemelni kívánt és meghatározott szöveget, lásd a képernyőképet:

4. Kattintson a gombra OK gombra, az első oszlop összes megfelelő szövege a második oszlop konkrét szövege alapján pirosra színeződött a következő képernyőkép szerint:

Relatívabb cikkek: