Hogyan lehet elérni a mappák listáját az Outlook programban?

Néha a Navigációs ablaktábla összes levelezõmappájának (beleértve a létrehozott személyes mappákat is) faszerkezete segítséget nyújthat az Outlook felhasználók számára a munkájuk során. A teljes faszerkezeti mappák gyors felsorolásához a VBA-kód segíthet. Ebben az oktatóanyagban megtanulhatja, hogyan lehet a mappák listáját egyszerűen megszerezni a VBA kóddal.

Mappák listájának letöltése az Outlookban VBA kóddal

Mappák listájának letöltése az Outlookban VBA kóddal

Az Outlook mappák listájának VBA kóddal történő megszerzéséhez tegye a következőket.

1. megnyomni a más + F11 billentyűk megnyomásával Microsoft Visual Basic for Applications ablak.

2. Ezután kattintson duplán a gombra Project1 > Microsoft Outlook objektum > ThisOutlookSession megnyitni Project1 - ThisOutlookSession ablak. Lásd a képernyőképet:

3. Ezután másolja és illessze be az alábbi VBA kódot a Project1 - ThisOutlookSession ablakba.

VBA: mappák listájának lekérése az Outlook programban

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. megnyomni a F5 gombot a VBA kód futtatásához.

5. Most a Macro megjelenik a párbeszédpanel, kattintson a gombra futás gombot.

6. Várja meg, amíg a Makró fut. Ezután az összes e-mail mappa listája azonnal megjelenik egy létrehozott új üzenetablakban. Könnyen kinyomtathatja. Lásd a képernyőképet:

Megjegyzések: Ez a VBA-kód alkalmazható az Outlook 2007-re, 2010-re és 2013-ra.

---

Kutools for Outlook - 100 speciális funkciót hoz az Outlookba, és sokkal könnyebbé teszi a munkát!

• Auto CC / BCC szabályok szerint e-mail küldéskor; Automatikus továbbítás Több e-mail egyedi; Autómatikus válasz csere szerver és további automatikus funkciók nélkül ...
• BCC figyelmeztetés - üzenet megjelenítése, amikor megpróbál válaszolni az összesre ha az e-mail címed szerepel a BCC listában; Emlékeztessen a hiányzó mellékletekre, és további funkciók emlékeztetnek ...
• Válasz (minden) az összes melléklettel az e-mail beszélgetésben; Válasz sok e-mailre másodpercek alatt; Automatikus üdvözlet hozzáadása amikor válasz; Dátum hozzáadása a tárgyhoz ...
• Mellékleteszközök: Az összes levél összes mellékletének kezelése, Automatikus leválasztás, Tömörítsen mindent, Átnevezés, Összes mentése ... Gyorsjelentés, Számolja ki a kiválasztott leveleket...
• Erőteljes levélszemét szokás szerint; Távolítsa el az ismétlődő leveleket és névjegyeket... Lehetővé teszi, hogy okosabban, gyorsabban és jobban végezze el az Outlook programot.

Tovább ... Letöltés most...