Hogyan küldhetünk naptárat több címzettnek egyenként az Outlookban?

Általában a naptár segítségével gyorsan és egyszerűen elküldhet egy naptárt a címzettnek E-mail naptár funkció az Outlookban. Ha egy iCalendar fájlként csatolt naptárt külön-külön szeretne elküldeni több névjegynek, egyenként kell elküldenie. Ebben a cikkben arról fogok beszélni, hogy hogyan lehet egy naptárt több címzettnek külön-külön elküldeni az Outlookban.

Küldjön naptárat több címzettnek egyenként VBA kóddal

Küldjön naptárat több címzettnek egyenként VBA kóddal

Ha több címzettnek szeretne külön naptárt küldeni, a következő VBA-kód segíthet, kérjük, tegye a következőket:

1. Navigáljon a Kapcsolatok ablaktáblán válassza ki azokat a névjegyeket, amelyeknek naptárat szeretne küldeni.

2. Ezután tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

3. Kattints betétlap > Modulok, másolja és illessze be a kódot a megnyitott üres modulba, lásd a képernyőképet:

VBA kód: Naptár küldése több címzettnek egyenként ：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. A kód beillesztése után nyomja meg a gombot F5 kulcs a kód futtatásához, és a Válassza ki a Mappa kiugrott a párbeszédpanel, kérjük, válassza ki a küldeni kívánt naptárt, lásd a képernyőképet:

5. Kattints OK, majd adja meg a dátumtartományt, amelyre el szeretné küldeni a naptárt, a következő prompt dobozokban:

6. Ezután kattintson OK, új e-maileket csatolt naptárral hoztunk létre az alábbi képernyőképen látható módon, akkor csak egyesével kell elküldenie őket.