Hogyan állítsunk be különféle aláírásokat a válaszokhoz és az továbbításokhoz az Outlookban?

Normál esetben különböző aláírásokat állíthat be a különböző fiókokhoz az Outlook programban, de megpróbáltak már más-más aláírást alkalmazni a válaszok és továbbítások során. Ez azt jelenti, hogy amikor válaszol egy e-mailre, az aláírás1 kerül beillesztésre, e-mail továbbításakor az aláírás2 kerül alkalmazásra. Hogyan oldhatná meg ezt a feladatot az Outlook programban?

Állítson be különböző aláírásokat a VBA kóddal ellátott válaszokhoz és továbbításokhoz

Állítson be különböző aláírásokat a VBA kóddal ellátott válaszokhoz és továbbításokhoz

A következő VBA-kód segíthet különböző aláírások beállításában a válaszokhoz és a továbbításokhoz, kérjük, tegye meg az alábbi lépéseket egyesével:

1. Tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

2. Ezután kattints a gombra betétlap > Modulok, másolja és illessze be a kódot a megnyitott üres modulba, lásd a képernyőképet:

VBA kód: Különböző aláírások beállítása a válaszokhoz és a továbbításokhoz:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

Megjegyzések: A fenti kódban Aláírás1 és a Aláírás2 az a két aláírásnév, amelyet válaszoláshoz és továbbításhoz használni kíván. Kérjük, változtassa meg a neveket igényeinek megfelelően.

doc sig forwar válasz 1

3. Még mindig a Microsoft Visual Basic for Applications ablakban kattintson Eszközök > Referenciák menni Referenciák-Projekt1 párbeszédpanelt, és ellenőrizze Microsoft Scripting Runtime lehetőség a Elérhető referenciák lista mező, lásd a képernyőképet:

doc sig forwar válasz 2

4. Kattintson a gombra OK a párbeszédablak bezárásához, mostantól kezdve, amikor válaszol egy e-mailre, az Signature1 azonnal be lesz helyezve, lásd a képernyőképet:

doc sig forwar válasz 3