Hogyan nyomtathatunk feladatokat kategóriák alapján az Outlook programban?

Tegyük fel, hogy az Outlook-feladatokban különféle színkategóriák vannak, és most a különböző oldalak kategóriái alapján szeretné kinyomtatni a feladatlistákat. Hogyan oldhatná meg ezt a munkát az Outlook programban?

Különféle oldalak kategóriái alapján nyomtasson feladatokat manuálisan, egyesével

Feladatok nyomtatása kategóriák alapján különböző oldalakon, VBA kóddal

Különféle oldalak kategóriái alapján nyomtasson feladatokat manuálisan, egyesével

Az Outlookban manuálisan kinyomtathatja a feladatokat a különböző kategóriák alapján, különböző oldalakon, kérjük, tegye a következőket:

1. Indítsa el az Outlook programot, lépjen a Feladat ablaktáblára, válassza ki a nyomtatni kívánt feladatmappát, majd nyomja meg az gombot Ctrl + E aktiválni a Keresés mezőbe, majd a Keresés fülre kattintva kategorizált ikont, és válasszon egy színkategóriát, amelyet nyomtatnia kell, lásd a képernyőképet:

doc nyomtatási feladatok 1. kategória szerint

2. Ezután az összes színkategóriával rendelkező feladat egyszerre jelenik meg, lásd a képernyőképet:

doc nyomtatási feladatok 2. kategória szerint

3. Ezután kattintson a gombra filé > a feladatlista kinyomtatásához az alábbi képernyőképen:

doc nyomtatási feladatok 3. kategória szerint

4. Ismételje meg a fenti lépéseket a feladatlisták más színkategóriákkal történő egyesével történő manuális kinyomtatásához.

Feladatok nyomtatása kategóriák alapján különböző oldalakon, VBA kóddal

Itt van egy VBA kód, amely segíthet a kategóriák szerinti feladatok egyszerre történő kinyomtatásában a különböző oldalakon, kérjük, tegye a következőket:

1. Menjen a Feladat ablaktáblán válassza ki a nyomtatni kívánt feladatmappát.

2. Ezután tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

3. Ezután kattintson betétlap > Modulok, másolja és illessze be a kódot a megnyitott üres modulba:

VBA kód: Feladatok nyomtatása kategóriák alapján különböző oldalakon:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Ezután kattintson Eszközök > Referenciák a Microsoft Visual Basic for Applications ablak, a kiugrott Referenciák-Projekt1 párbeszédpanelen ellenőrizze Microsoft Excel objektumkönyvtár és a Microsoft Scripting Runtime lehetőségek a Elérhető referenciák lista mező, lásd a képernyőképet:

doc nyomtatási feladatok 4. kategória szerint

5. Ezután kattintson OK gombot, most nyomja meg F5 kulcs a kód futtatásához, a kód befejezése után a különböző kategóriájú feladatok listája különféle oldalakon kerül kinyomtatásra.