Hogyan válaszoljak normálisan az Outlook küldött elemek mappájába? 

Normál esetben, amikor az Elküldött elemek mappában található Válasz funkció elemre kattint, és újabb üzenetet küld az Ön számára elküldött személyek számára, a saját e-mail címe megjelenik a Címzett mezőben, a következő képernyőkép szerint. Ez bosszantó lehet, ha minden alkalommal megváltoztatja a címet. Hogyan tudná az Outlook használni az eredeti címzett címét, nem pedig a sajátját?

Válaszoljon az Elküldött elemek mappába az Outlook Válasz az összes funkcióval

Válaszoljon normálisan az Elküldött elemek mappába az Outlookból, VBA kóddal

---

Válaszoljon az Elküldött elemek mappába az Outlook Válasz az összes funkcióval

Az Outlookban a Válasz mindenkinek funkció segítségével megoldhatja ezt a problémát, kérjük, tegye a következőket:

Ha meg kell válaszolnia az elküldött e-mailt az elküldésre, hogy megőrizze az eredeti címzett címét, kattintson a gombra Válasz mindenkinek gombra, és az eredeti címzett címe a Nak nek mező a következő képernyőképen látható:

---

Válaszoljon normálisan az Elküldött elemek mappába az Outlookból, VBA kóddal

Valamikor elfelejtheti a Válasz mindenkinek funkció az elküldött üzenet megválaszolásakor, így az alábbi VBA-kód segíthet a Normál válaszadásban az Elküldött elemek mappában a Válasz funkció használatával. Tegye a következő lépésekkel:

1. Tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

2. Az Microsoft Visual Basic for Applications ablakban kattintson duplán ThisOutlookSession tól Project1 (VbaProject.OTM) ablaktáblán nyissa meg a módot, majd másolja és illessze be a következő kódot az üres modulba.

VBA-kód: Válaszoljon normálisan az Elküldött elemek mappába az Outlookból:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Ezután mentse el a kódot, és indítsa újra az Outlook programot a kódhatás eléréséhez, amikor rákattint Válasz e-mail újraküldéséhez Elküldött elemek mappában az eredeti címzett címe a Címzett mezőben jelenik meg, amire szüksége van.