Excel CHOOSE funkció
- Ex1 - Alapvető használat: használat CHOOSE csak a függvény segítségével választhat értéket a lista argumentumból
- Ex2 - Különböző eredmények visszaadása több feltétel alapján
- Ex3 - Különböző számított eredményeket adhat vissza a feltételek alapján
- Ex4 - Válasszon véletlenszerűt a listából
- Ex5 - Össze CHOOSE és a VLOOKUP függvények a bal oldali oszlop értékének visszaadásához
- Ex6 - Hétköznap vagy hónap visszatérése a megadott dátum alapján
- Ex7 - Vissza a következő munkanap / hétvége dátumra a mai alapján
Leírás
A CHOOSE függvény ad vissza egy értéket az adott argumentum listájáról a megadott indexszám alapján. Például, CHOOSE(3,”Apple”,”Peach”,”Orange”) narancssárga értéket ad vissza, az index száma 3, a narancs pedig a függvény indexszáma után a harmadik érték.
szintaxis és érvek
Képlet szintaxisa
CHOOSE(index_num, value1, [value2], …) |
érvek
|
Value1, value2… Lehetnek számok, szövegek, képletek, cellahivatkozások vagy meghatározott név.
Visszatérési érték
A CHOOSE függvény ad vissza egy értéket egy listából az adott pozíció alapján.
Használat és példák
Ebben a részben néhány egyszerű, de reprezentatív példát sorolok fel a CHOOSE funkciót.
Ex1 - Alapvető használat: használat CHOOSE csak a függvény segítségével választhat értéket a lista argumentumból
Forma-1:
=CHOOSE(3,"a","b","c","d")
Return: c, amely a harmadik argumentum a 3 index_száma után a CHOOSE funkciót.
Megjegyzés: az értéket körülvevő dupla idézőjelek használata, ha ez szöveg.
Forma-2:
=CHOOSE(2,A1,A2,A3,A4)
Vissza: Kate, az A2 értéke. Mivel az index_száma 2, és A2 az érték második értéke CHOOSE funkciót.
Forma-3:
=CHOOSE(4,8,9,7,6)
Return: 6, a függvény 4. lista argumentuma.
Ex2 - Különböző eredmények visszaadása több feltétel alapján
Tételezzük fel, hogy minden termékhez tartozik egy olyan eltérés, amelyet fel kell tüntetni az alábbi képen látható feltételek alapján.
Általában az IF függvényt kezelheti, de itt bemutatom az CHOOSE funkciót a probléma könnyű megoldására
képlet:
=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")
Magyarázza el:
(B7>0)+(B7>1)+(B7>5): Az index_száma, B7 2, amely nagyobb, mint 0 és 1, de kevesebb, mint 5, így megkapjuk a köztes eredményt:
=CHOOSE(True+Ture+False,"Top","Middle","Bottom")
Mint tudjuk, True = 1, False = 0, így a képlet a következőképpen tekinthető meg:
=CHOOSE(1+1+0,"Top","Middle","Bottom")
akkor
=CHOOSE(2,"Top","Middle","Bottom")
Eredmény: Közép
Ex3 - Különböző számított eredményeket adhat vissza a feltételek alapján
Tegyük fel, hogy ki kell számolnia az egyes termékek árengedményeit az összeg és az ár alapján, az alábbi képernyőképen:
képlet:
=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
Magyarázza el:
(B8>0)+(B8>100)+(B8>200)+(B8>300): index_szám, a B8 102, ami nagyobb, mint 100, de kevesebb, mint 201, tehát ebben a részben a következőképpen megjelenített eredményt adja vissza:
=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
akkor
=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: az értékek, amelyek közül választhatunk, az árengedmény megegyezik az ár * összeg * engedmény százalékkal, mivel itt az index_száma 2, akkor a B8 * C8 * 0.2 értéket választja
Visszatérés: 102 * 2 * 0.2 = 40.8
Ex4 - Válasszon véletlenszerűt a listából
Az Excel programban néha előfordulhat, hogy véletlenszerűen kell kiválasztania egy értéket egy adott listából, a CHOOSE funkció megoldhatja ezt a munkát.
Véletlenszerűen válasszon ki egy értéket a listából:
képlet:
=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)
Magyarázza el:
RANDBETWEEN(1,5): index_num, véletlenszerűen szerezzen be 1 és 5 közötti számot
$D$2,$D$3,$D$4,$D$5,$D$6: az értékek listája, amelyek közül választhat
Ex5 - Össze CHOOSE és a VLOOKUP függvények a bal oldali oszlop értékének visszaadásához
Általában a VLOOKUP függvényt használjuk =VLOOKUP (value, table, col_index, [range_lookup]) egy adott tartományon alapuló érték visszaadásához egy táblázattartományból. De a VLOOKUP függvény esetén hibaértéket ad vissza, miközben a visszatérő oszlop a keresési oszlop bal oldalán található, az alábbi képernyőképen:
Ebben az esetben kombinálhatja a CHOOSE funkció a VLOOKUP funkcióval a probléma megoldására.
képlet:
=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)
Magyarázza el:
CHOOSE({1,2},B1:B7,A1:A7): mint table_range argumentum a VLOOKUP függvényben. Az {1,2} azt jelenti, hogy 1 vagy 2 index_num argumentumként jelenjen meg a col_num argumentum alapján a VLOOKUP függvényben. Itt a col_num a VLOOKUP függvényben 2, tehát a CHOOSE funkció kijelzése as CHOOSE(2, B1:B7,A1:A7), azt jelenti, hogy értéket válasszon az A1: A7 közül.
Ex6 - Hétköznap vagy hónap visszatérése a megadott dátum alapján
Aktivitáskövető CHOOSE függvény esetén a relatív hétnapot és hónapot is visszaadhatja egy adott dátum alapján.
1 képlet: térjen vissza a hétköznapokra egy dátummal
=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")
Magyarázza el:
WEEKDAY(): az index_száma argumentum, hogy megkapja az adott dátum hétköznapi számát, például a WEEKDAY (A5) 6-ot ad vissza, akkor az index_száma argumentum 6.
"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": értéklista argumentumok, kezdje a „vasárnap” betűvel, mert az „1” hétköznapi szám a „vasárnapot” jelöli.
2 képlet: visszatérési hónap dátum szerint
=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")
Magyarázza el:
MONTH(): index_num argumentum, amely megkapja a hónap számát az adott dátumtól, például a MONTH (A5) 3-at ad vissza.
Ex7 - Vissza a következő munkanap / hétvége dátumra a mai alapján
A mindennapi munkában érdemes a mai munkanapot vagy hétvégét a mai alapján kiszámítani. Itt a CHOOSE funkció is tehet egy szívességet.
Például ma 12., Csütörtök, most meg kell szereznie a következő munkanapot és hétvégét.
1 képlet: kapd meg a mai dátumot
=TODAY()
Eredmény: 12
2 képlet: kapja meg a mai hétköznapi számot
=WEEKDAY(TODAY())
Eredmény: 5 (míg ma 12. Van)
A hétköznapi számok listája az alábbi képernyőképen:
3 képlet: megkapja a következő munkanapot
=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)
Magyarázza el:
Today(): adja vissza az aktuális dátumot
WEEKDAY(TODAY()): index_num argumentum a CHOOSE függvény, kapja meg a mai hétköznapi számot, például vasárnap 1, hétfő 2…
1,1,1,1,1,3,2: értéklista argumentum a CHOOSE funkció. Például, ha a hétköznap (ma ()) értéke 1 (vasárnap), akkor az értékek listájából 1 értéket választ, akkor az egész képlet = Mai () + 1 értékre változik, ami azt jelenti, hogy 1 napot ad hozzá a jövő hétfői visszatéréshez. Ha a hétköznap (ma ()) értéke 6 (péntek), akkor az értékek közül 3-at választ, mert a péntek 3 napra van a jövő hétfőtől.
Eredmény (míg ma 12. Van):
=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)
= 12 + 20
= 12
4 képlet: kap a következő hétvégi napon
=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)
Magyarázza el:
6,5,4,3,2,1,1: értéklista argumentum a CHOOSE funkció. Például, ha a hétköznap (ma ()) 1-re tér vissza (vasárnap), akkor az értékek listájából 6-ot választja, akkor az egész képlet = Today () + 6-ra változik, ami azt jelenti, hogy 6 napot adunk hozzá, és jövő szombaton visszatérünk.
Eredmény:
=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)
= 12 + 20
= 12
A legjobb irodai termelékenységi eszközök
Kutools for Excel - segít kitűnni a tömegből
A Kutools for Excel több mint 300 funkcióval büszkélkedhet, Győződjön meg arról, hogy amire szüksége van, csak egy kattintásnyira van...
Office lap – A lapos olvasás és szerkesztés engedélyezése a Microsoft Office programban (beleértve az Excelt is)
- Egy másodperc a tucatnyi nyitott dokumentum közötti váltáshoz!
- Csökkentse az egérkattintások százait az Ön számára minden nap, búcsút mondjon az egér kezének.
- 50% -kal növeli a termelékenységet több dokumentum megtekintésekor és szerkesztésekor.
- Hatékony lapokat hoz az Office-ba (beleértve az Excelt is), akárcsak a Chrome, az Edge és a Firefox.