Note: The other languages of the website are Google-translated. Back to English

Excel SUMIF funkció

Az Excelben a SUMIF függvény segíthet a cellák összegzésében egy kritérium alapján. Ez a cikk elmagyarázza ennek a függvénynek a szintaxisát, és bemutat néhány példát a SUMIF függvény használatára.


 Syntax:

Az SUMIF függvény szintaxisa az Excelben:

=SUMIF (range, criteria, [sum_range])

 érvek:

  • range: Kötelező. Az a cellatartomány, amelyre alkalmazni szeretné a feltételeket.
  • criteria: Kötelező. A hozzáadandó sejtek meghatározásához használt kritériumok. A kritériumok lehetnek szöveg, szám, dátum, logikai kifejezés, cellahivatkozás vagy más függvény.
  • Megjegyzések: A szöveges kritériumokat vagy matematikai szimbólumokat tartalmazó feltételeket dupla idézőjelek közé kell tenni. Ha a kritérium numerikus, dupla idézőjelek nem szükségesek.
  • sum_range:Választható. A cellák tartománya az összegzés. Ha ezt a paramétert kihagyja, akkor a tartományt használja a összeg_tartomány.

 Visszatérés:

Adja vissza az összesítést a számok listájához a konkrét kritériumok alapján.


 Példák:

1. példa: Összegezzen, ha az értékek nagyobbak, kisebbek, egyenlőek vagy más összehasonlító operátorok

Az Excelben a SUMIF függvény segítségével összeadhatja az adott feltételnél nagyobb, kisebb, egyenlő vagy nem egyenlő értékeket.

Tegyük fel, hogy van egy táblázata, amely Név, Mennyiség és Ár oszlopokat tartalmaz, az alábbi képernyőképen, hogyan lehet elérni azt a teljes árat, hogy a Mennyiség meghaladja a 250-et?

Kérjük, alkalmazza az alábbi képletet egy üres cellába:

=SUMIF(B2:B8,">250",C2:C8)
  • tippek: A fenti képletben:
  • B2: B8: az a cellatartomány, ahol a kritériumok keresésre kerülnek.
  • "> 250": az a feltétel, amely alapján összegezni szeretné a cellaértékeket.
  • C2: C8: az összegezendő tartományra utal.

Ezután nyomja meg a gombot belép kulcs a teljes ár megszerzéséhez, hogy a Mennyiség meghaladja a 250-et, az alábbi képernyőképen:

Megjegyzések: Használhat más összehasonlító operátorokat is, például nagyobb vagy egyenlő (> =), kisebb (<), kisebb vagy egyenlő (<=), egyenlő (=), nem egyenlő (<>) - szükséglete.


2. példa: SUMIF képletek szöveges feltételekkel

Ha összegezni szeretné a cellák értékeit annak alapján, hogy létezik-e egy adott szövegérték egy másik oszlopban, akkor a SUMIF függvény is szívességet tehet Önnek.


1. eset: Összegezze a cellaértékeket, ha egy másik oszlopban konkrét szöveget tartalmaz

Vegyük példaként az alábbi adatokat, hogy megkapjuk a teljes mennyiséget, ha a név David az A oszlopban.

Kérjük, írja be vagy másolja az alábbi képletet egy üres cellába:

=SUMIF(A2:A8, "David", B2:B8)
  • tippek: A fenti képletben:
  • A2: A8: az a cellatartomány, ahol a kritériumok keresésre kerülnek.
  • „Dávid”: az a feltétel, amely alapján összegezni szeretné a cellaértékeket.
  • B2: B8: az összesítendő cellák tartománya.

Megjegyzések: Használhatja a cella hivatkozást a fenti képlet feltételének helyettesítésére is: =SUMIF(A2:A8, D2, B2:B8).


2. eset: Az összesítő cellák értéke nem egyenlő egy adott értékkel

Ha összegezni szeretné a cellákat, amikor a cellák nem egyenlőek egy adott értékkel, például David összes kivételével az emberek összes mennyiségét összegezni, hogyan tehette meg?

Kérjük, alkalmazza az alábbi képletet egy üres cellába:

=SUMIF(A2:A8, "<>David", B2:B8)
  • tippek: A fenti képletben:
  • A2: A8: az a cellatartomány, ahol a kritériumok keresésre kerülnek.
  • "<> David": az a feltétel, amely alapján összegezni szeretné a cellaértékeket.
  • B2: B8: az összesítendő cellák tartománya.

Megjegyzések: Használhatja a cella hivatkozást a fenti képlet feltételének helyettesítésére is: =SUMIF(A2:A8,"<>"&D2, B2:B8), a dupla idézőjeleket ("") kell használnia az összehasonlító operátorok becsatolásához, az ampersand (&) pedig a cella referencia összefűzéséhez. Lásd a képernyőképet:


3. példa: SUMIF képletek helyettesítő karakterekkel

Néha előfordulhat, hogy a pontos érték helyett a részleges szöveges egyezés alapján kell összegeznie a cellaértékeket. Ebben az esetben a csillag (*) vagy a kérdőjel (?) Helyettesítő karaktereket kombinálhatja a SUMIF funkcióval.

Csillag (*): Bármennyi karaktert képvisel

Kérdőjel (?): Bármelyik karaktert képvisel egy adott pozícióban


1. eset: A csillag (*) karakterrel való részleges egyezésen alapuló összegek

Például van egy táblázatom, amely a következő képernyőképen látható, most szeretném összegezni a termék összes megrendelését, amely szöveg tartalmazza a Kutools-t.

Kérjük, alkalmazza a következő képletet egy üres cellába:

=SUMIF(A2:A8, "*Kutools*", B2:B8)

Ezután nyomja meg a gombot belép gombot az alábbi eredmény eléréséhez:

Megjegyzések:

1. Ha összegezni szeretné a Kutools-szal kezdődő cellaértékeket, használja ezt a képletet: = SUMIF (A2: A8, "Kutools *", B2: B8).

2. A cellaértékek összegzéséhez, ha az A oszlop megfelelő cellája a Kutools szöveggel végződik, kérjük, használja ezt a képletet: = SUMIF (A2: A8, "* Kutools", B2: B8).

3. Használhatja a cella hivatkozást a fenti képlet feltételének helyettesítésére is: =SUMIF(A2:A8, "*"&D2&"*", B2:B8). Használja a dupla idézőjeleket ("") a csillag bezárásához, az ampersand (&) pedig a cella referencia összefűzéséhez. Lásd a képernyőképet:


2. eset: Az értékek összege meghatározott számú karakterrel, kérdőjellel (?)

Ha össze szeretné foglalni a cellaértékeket egy listában, melyik cella pontosan 5 karakter hosszú, ahogy a következő képernyőkép látható. Hogyan oldhatná meg ezt a feladatot Excelben?

A munka kezeléséhez alkalmazza az alábbi képletet:

=SUMIF(A2:A8, "?????", B2:B8)

típus: Ebben a képletben: egy kérdőjel egyetlen karaktert jelöl, az öt kérdőjel 5 karakter hosszúságot jelöl.

És akkor nyomja meg belép gombot, megkapja a kívánt eredményt:


4. példa: Az üres vagy nem üres celláknak megfelelő cellák értékének összegzése

Az Excelben a SUMIF függvény abban is segít, hogy összegezze a listában szereplő értékeket, miszerint a szomszédos cella üres vagy nem üres cella.


1. eset: A cellaértékek összegzése, ha a szomszédos cella üres

Kérjük, írja be vagy másolja az alábbi képletek bármelyikét egy cellába, ahol az eredményt szeretné elérni:

=SUMIF(A2:A8,"=",B2:B8)
=SUMIF(A2:A8,"",B2:B8)

Ezután nyomja meg a gombot belép kulcs a teljes ár eredményének megszerzéséhez, ha az A oszlopban üres cellák vannak, lásd a képernyőképet:


2. eset: A cellaértékek összegzése, ha a szomszédos cella nem üres cella

Ha összegeznie kell azokat az értékeket, amelyekben a szomszédos cellák tartalmaznak üres cellák nélküli szövegeket, alkalmazza az alábbi képletet:

=SUMIF(A2:A8,"<>",B2:B8)

És akkor nyomja meg belép kulcs, összesítettük az összes olyan értéket, ahol a szomszédos cellák értékeket tartalmaznak, lásd a képernyőképet:


5. példa: SUMIF dátumokkal az Excel-ben

Normál esetben a SUMIF függvényt is felhasználhatja az Excel dátumán alapuló értékek összegzésére.


1. eset: Összegértékek, ha a dátum aktuális dátum vagy ennél kisebb, nagyobb, mint a mai

A cellaértékek összegzéséhez, hogy melyik dátum az aktuális dátum, használhatja az alábbi képletet:

=SUMIF(B2:B8, TODAY(), C2:C8)

Ezután nyomja meg a gombot belép kulcs, összesíti azokat a cellákat, amelyeknek a megfelelő dátum ma van. Lásd a képernyőképet:

Megjegyzések:

1. Az értékek összegzéséhez, ha a megfelelő dátum kevesebb, mint ma, kérjük, használja ezt a képletet: = SUMIF (B2: B8, "<" & TODAY (), C2: C8).

2. Az értékek összegzéséhez, ha a megfelelő dátum nagyobb, mint a mai vagy későbbi, kérjük, használja ezt a képletet: = SUMIF (B2: B8, ">" & TODAY (), C2: C8).


2. eset: Az összegek két megadott dátum között

Ha összegezni szeretné az értékeket, ha a dátum két megadott dátum között van, akkor két SUMIF függvényt kombinálhat a feladat megoldásához.

Kérjük, alkalmazza az alábbi képletet:

=SUMIF(B2:B8, ">=6/15/2019", C2:C8) - SUMIF(B2:B8, ">=7/31/2019", C2:C8)

Ezután nyomja meg az Enter billentyűt, a két megadott dátum közötti teljes érték kiszámításra került, lásd a képernyőképet:

Megjegyzések: Használhatja a cella hivatkozást a fenti képlet feltételének helyettesítésére is: = SUMIF (B2: B8, "> =" & E2, C2: C8) - SUMIF (B2: B8, "> =" & F2, C2: C8), lásd a képernyőképet:


6. példa: Az értékek összegzése az Excel több oszlopában

Ez a SUMIF függvény segíthet abban is, hogy az értékeket több oszlopban összegezze egy feltétel alapján. Például, ha rendelkezik az alábbi képernyőképen látható adatsorral, akkor kapja meg a termék KTE összes értékét négy hónap alatt - január, február, március és április. Hogyan tehette meg?

Normál esetben a SUMIF függvényt egy kritérium alapján értékoszlop összegzésére használják, több oszlopban lévő értékek összegzésére, a feladat megoldásához több SUMIF függvényt kombinálhat.

Kérjük, alkalmazza az alábbi képletet egy üres cellába:

=SUM(SUMIF(A2:A8,G2,B2:B8), SUMIF(A2:A8,G2,C2:C8), SUMIF(A2:A8,G2,D2:D8),SUMIF(A2:A8,G2,E2:E8))

Ezután nyomja meg az Enter gombot a kívánt eredmény eléréséhez, lásd a képernyőképet:

Megjegyzések: A fenti SUMIF függvény kissé nehezen használható, ha sok oszlopot kell összegezni, ezért itt egy egyszerű SUMPRODUCT függvény segíthet ebben a munkában is. Kérjük, használja ezt a képletet: =SUMPRODUCT((A2:A8=G2)*(B2:E8)), majd nyomja meg a gombot belép kulcs az eredmény eléréséhez:

  • tippek: A fenti képletben:
  • A2: A8: az a cellatartomány, ahol a kritériumok keresésre kerülnek.
  • G2: az a feltétel, amely alapján összegezni szeretné a cellaértékeket.
  • B2: E8: az összesítendő cellák tartománya.


 További SUMIF funkció cikkek:

  • Összegezze a megfelelő értékeket ugyanabban a dátumban az Excelben
  • Megpróbálta már összegyűjteni a megfelelő értékeket ugyanazon dátum alapján az Excel egy másik oszlopából? Tételezzük fel, hogy a következő adattartománnyal rendelkezem (A1: B13), az A oszlopban a dátumtartomány tartalmaz néhány ismétlődő dátumot, a B oszlopban pedig a sorrend száma található, most az oszlopban ugyanazon dátum alapján kell összeadnom a számokat A. Hogyan lehet gyorsan és egyszerűen befejezni az Excelben?
  • A sumif dátum kevesebb / nagyobb, mint ma az Excelben
  • Tételezzük fel, hogy rendelkezünk értékesítési mennyiség táblázattal, amely tartalmazza a tervezés és a tényleges mennyiségeket. Most meg kell számolnunk a mai előtti dátumokat, és ki kell számolnunk a mai előtti teljes tervezési mennyiséget, hogy dinamikusan összehasonlíthassuk a tervezési mennyiségeket és a tényleges mennyiségeket. Itt alkalmazom a SUMIF függvényt, hogy gyorsan elkészüljön az Excel programban.
  • Sumif egy vagy több kritériummal az Excelben
  • Az Excel programban az egy vagy több kritériumon alapuló összegek általános feladata a legtöbbünk számára, a SUMIF függvény segíthet abban, hogy gyorsan összeadjuk az értékeket egy feltétel alapján, a SUMIFS függvény pedig több kritériummal rendelkező értékek összegzésében. Ebben a cikkben leírom, hogyan lehet összegezni egy vagy több kritériummal az Excelben?
  • Összeg az Excel részleges egyezése alapján
  • Vegyük példaként az alábbi adatokat: Szeretném összegezni a B oszlop celláinak értékeit, ha az A. oszlopban részleges „KTE” szöveg található. Hogyan érhető el? Ebben a cikkben arról fogok beszélni, hogyan lehet összegezni a cellák értékeit egy részleges egyezés alapján az Excel munkalapon.

A legjobb irodai termelékenységi eszközök

Kutools for Excel - segít kitűnni a tömegből

Szeretnéd gyorsan és tökéletesen elvégezni mindennapi munkádat? A Kutools for Excel 300 hatékony speciális funkciót kínál (munkafüzetek összevonása, színenkénti összegzés, cellatartalom felosztása, dátum konvertálása stb.), és 80%-os időt takaríthat meg Önnek.

  • 1500 munkaforgatókönyvhöz tervezve, segít megoldani az Excel problémák 80%-át.
  • Csökkentse a napi billentyűzet és egér kattintások ezreit, enyhítse fáradt szemét és kezét.
  • Legyen Excel szakértő 3 perc alatt. Nem kell többé emlékezni semmilyen fájdalmas képletre és VBA kódra.
  • 30 napos korlátlan ingyenes próbaidőszak. 60 napos pénzvisszafizetési garancia. Ingyenes frissítés és támogatás 2 évre.
Az Excel szalagja (telepítve a Kutools for Excel programmal)

Office fül - Füles olvasás és szerkesztés engedélyezése a Microsoft Office alkalmazásban (beleértve az Excel programot is)

  • Egy másodperc a tucatnyi nyitott dokumentum közötti váltáshoz!
  • Csökkentse az egérkattintások százait az Ön számára minden nap, búcsút mondjon az egér kezének.
  • 50% -kal növeli a termelékenységet több dokumentum megtekintésekor és szerkesztésekor.
  • Hatékony lapokat hoz az Office-ba (beleértve az Excel-t is), akárcsak a Chrome-ot, a Firefox-ot és az új Internet Explorert.
Az Excel képernyőképe (az Office Tab telepítve)
A megjegyzések rendezése szerint
Hozzászólások (0)
Még nincs értékelés. Legyen Ön az első, aki értékel!
Még senki sem írt megjegyzést
Hagyja meg észrevételeit
Feladás vendégként
×
Értékeld ezt a bejegyzést:
0   Karakterek
Javasolt helyek

Kövess minket

Copyright © 2009 - www.extendoffice.com. | Minden jog fenntartva. Powered by ExtendOffice. | Oldaltérkép
A Microsoft és az Office logó a Microsoft Corporation védjegyei vagy bejegyzett védjegyei az Egyesült Államokban és / vagy más országokban.
Sectigo SSL védi