Ugrás a tartalomra

Excel INDEX MATCH: Alapvető és haladó keresések

Az Excelben gyakran szükséges bizonyos adatok pontos lekérése. Míg az INDEX és a MATCH funkcióknak megvannak a maga erősségei, ezek kombinálása hatékony eszközkészletet nyit az adatkereséshez. Együtt a keresési lehetőségek széles skáláját teszik lehetővé, az alapvető vízszintes és függőleges keresésektől a fejlettebb funkciókig, mint például a kétirányú, kis- és nagybetűk megkülönböztetése és a több feltétel alapján történő keresés. A VLOOKUP-hoz képest továbbfejlesztett képességeket kínálva az INDEX és a MATCH párosítása az adatkeresési lehetőségek szélesebb körét teszi lehetővé. Ebben az oktatóanyagban ássuk be a közösen elérhető lehetőségek mélységét.


Az INDEX és a MATCH használata Excelben

Mielőtt az INDEX és MATCH függvényeket használnánk, győződjön meg arról, hogy tudjuk, hogyan segíthet az INDEX és a MATCH az értékek keresésében.


Az INDEX függvény használata Excelben

Az INDEX függvény az Excelben egy adott helyen, egy adott tartományban lévő értéket adja vissza. Az INDEX függvény szintaxisa a következő:

=INDEX(array, row_num, [column_num])
  • sor (kötelező) arra a tartományra vonatkozik, ahonnan vissza szeretné adni az értéket.
  • sor_szám (kötelező, hacsak nem oszlop_száma jelen van) a tömb sorszámára utal.
  • oszlop_száma (nem kötelező, de kötelező, ha sor_szám ki van hagyva) a tömb oszlopszámára utal.

Például tudni a kotta Jeff, a 6A listán szereplő tanulók közül a következőképpen használhatja az INDEX függvényt:

=INDEX(C2:C11,6)

excel index egyezés 01

√ Megjegyzés: A tartomány C2: C11 ahol a pontszámok szerepelnek, míg a szám 6 megkeresi a vizsgapontszámot 6th diák.

Tegyünk egy kis tesztet. A képlethez =INDEX(A1:C1,2;XNUMX), milyen értéket ad vissza? --- Igen, vissza fog térni Születési dátum, a 2nd érték az adott sorban.

Most már tudnunk kell, hogy az INDEX funkció tökéletesen működik vízszintes vagy függőleges tartományokkal. De mi van akkor, ha arra van szükségünk, hogy egy nagyobb, több sorral és oszloppal rendelkező tartományban lévő értéket adjunk vissza? Nos, ebben az esetben sorszámot és oszlopszámot is alkalmaznunk kell. Például, hogy megtudja Jeff pontszáma táblázat tartományán belül egyetlen oszlop helyett a pontszámát a-val tudjuk megkeresni 6-as sorszám és egy 3-as oszlopszám a sejteket A2-től C11-ig mint ez:

=INDEX(A2:C11,6,3)

excel index egyezés 02

Amit tudnunk kell az Excel INDEX függvényéről:
  • Az INDEX funkció függőleges és vízszintes tartományokkal is működhet.
  • Ha mindkettő sor_szám és a oszlop_száma érveket használnak, sor_szám megelőzi a oszlop_száma, és az INDEX lekéri a megadott metszéspontjában lévő értéket sor_szám és a oszlop_száma.

Egy igazán nagy, több sorból és oszlopból álló adatbázis esetében azonban biztosan nem kényelmes, ha a képletet pontos sor- és oszlopszámmal alkalmazzuk. És ez az, amikor kombinálnunk kell a MATCH függvény használatát.


A MATCH funkció használata Excelben

Az Excel MATCH függvénye egy numerikus értéket ad vissza, egy adott elem helyét az adott tartományban. A MATCH függvény szintaxisa a következő:

=MATCH(lookup_value, lookup_array, [match_type])
  • keresési_érték (kötelező) a megfelelő értékre utal lookup_array.
  • lookup_array (kötelező) a cellák azon tartományára utal, ahol a MATCH keresni kíván.
  • match_type (választható): 1, 0 or -1.
    • 1 (alapértelmezett), a MATCH megtalálja a legnagyobb értéket, amely kisebb vagy egyenlő keresési_érték. Az értékek a lookup_array növekvő sorrendben kell elhelyezni.
    • 0A MATCH megkeresi az első értéket, amely pontosan megegyezik a keresési_érték. Az értékek a lookup_array bármilyen sorrendben lehet. (Azokban az esetekben, amikor az egyezés típusa 0, használhat helyettesítő karaktereket.)
    • -1, A MATCH megtalálja a legkisebb értéket, amely nagyobb vagy egyenlő keresési_érték. Az értékek a lookup_array csökkenő sorrendben kell elhelyezni.

Például tudni Vera helye a névjegyzékben, használhatja a MATCH képletet a következőképpen:

=MATCH("Vera",A2:A11,0)

excel index egyezés 3

√ Megjegyzés: A „4” eredmény azt jelzi, hogy a „Vera” név a lista 4. pozíciójában található.

Amit tudnunk kell az Excel MATCH függvényéről:
  • A MATCH függvény a keresési érték pozícióját adja vissza a keresési tömbben, nem magát az értéket.
  • A MATCH függvény ismétlődés esetén az első egyezést adja vissza.
  • Az INDEX funkcióhoz hasonlóan a MATCH funkció függőleges és vízszintes tartományokkal is működhet.
  • A MATCH nem tesz különbséget a kis- és nagybetűk között.
  • Ha a keresési_érték A MATCH képlet szövege, idézőjelek közé írja be.
  • Ha a keresési_érték nem található a lookup_array, a # N / A hiba érkezik vissza.

Most, hogy ismerjük az INDEX és a MATCH függvények alapvető használatát az Excelben, tűrjük fel az ingujjunkat, és készüljünk a két funkció kombinálására.


Az INDEX és a MATCH kombinálása az Excelben

Tekintse meg az alábbi példát, hogy megtudja, hogyan kombinálhatjuk az INDEX és a MATCH függvényeket:

Megtalálni Evelyn pontszáma, annak tudatában, hogy a vizsgapontszámok a 3rd oszlopot, megtehetjük használja a MATCH funkciót a sorpozíció automatikus meghatározásához anélkül, hogy manuálisan meg kellene számolni. Ezt követően az INDEX függvényt használhatjuk a érték az azonosított sor és a 3. oszlop metszéspontjában:

=INDEX(A2:C11,MATCH("Evelyn",A2:A11,0),3)

excel index egyezés 4

Nos, mivel a képlet kissé bonyolultnak tűnhet, nézzük végig az egyes részeket.

excel index egyezés 5

Az INDEX a képlet három argumentumot tartalmaz:

  • sor_szám: MATCH("Evelyn",A2:A11,0;XNUMX) megadja az INDEX-et a "" érték sorpozíciójávalEvelyn" határon belül A2: A11, Amely 5.
  • oszlop_száma: 3 meghatározza a 3rd oszlopba az INDEX számára, hogy megkeresse a pontszámot a tömbön belül.
  • sor: A2: C11 utasítja az INDEX-et, hogy adja vissza az egyező értéket a megadott sor és oszlop metszéspontjában, a következő tartományon belül: A2-től C11-ig. Végül megkapjuk az eredményt 90.

A fenti képletben kemény kódolt értéket használtunk, "Evelyn". A gyakorlatban azonban a keménykódolt értékek nem praktikusak, mivel minden alkalommal módosítani kellene őket, amikor különböző adatokat keresünk, például egy másik tanuló pontszámát. Ilyen esetekben cellahivatkozásokat használhatunk dinamikus képletek létrehozására. Például ebben az esetben megteszem változtasd az "Evelyn"-t F2-re:

=INDEX(A2:C11,MATCH(F2,A2:A11,0),3)

(AD) Egyszerűsítse a keresést a Kutools segítségével: Nincs szükség képlet beírására!

Kutools az Excel számára's Szuper keresés biztosít különféle keresőeszközök minden igényét kielégíti. Akár több feltétel alapján keres, akár több munkalapon keres, akár egy a többhez keresést végez, Szuper keresés néhány kattintással leegyszerűsíti a folyamatot. Fedezze fel ezeket a funkciókat hogy hogyan Szuper keresés megváltoztatja az Excel-adatokkal való interakció módját. Mondjon búcsút az összetett képletek emlékezésének fáradságától.

Kutools keresőeszközök

Kutools az Excel számára - Több mint 300 praktikus funkcióval rendelkezik a könnyed termelékenység érdekében. Ne hagyja ki a lehetőséget, és próbálja ki egy 30 napos, teljes értékű ingyenes próbaverzióval! Kezd el most!


INDEX és MATCH képlet példák

Ebben a részben különböző körülményekről fogunk beszélni, hogy az INDEX és a MATCH függvényeket különböző igények kielégítésére használjuk.


INDEX és MATCH a kétirányú keresés alkalmazásához

Az előző példában tudtuk az oszlop számát, és egy MATCH képletet használtunk a sorszám megtalálásához. De mi van akkor, ha az oszlopszámban sem vagyunk biztosak?

Ilyen esetekben kétirányú keresést, más néven mátrixkeresést végezhetünk, két MATCH függvény használatával: az egyik a sorszám, a másik pedig az oszlopszám meghatározására szolgál. Például tudni Evelyn pontszáma, a következő képletet kell használnunk:

=INDEX(A2:C11,MATCH("Evelyn",A2:A11,0),MATCH("Score",A1:C1,0))

excel index egyezés 6

Hogyan működik ez a képlet:
  • Az első MATCH képlet megtalálja Evelyn helyét az A2:A11 listában, feltéve, hogy 5 az INDEX sorszámaként.
  • A második MATCH képlet határozza meg a pontszámok és a hozamok oszlopát 3 oszlopszámként az INDEX-hez.
  • A képlet leegyszerűsíti =INDEX(A2:C11,5,3;XNUMX), és az INDEX 90.

INDEX és MATCH a bal oldali keresés alkalmazásához

Most nézzünk meg egy forgatókönyvet, ahol meg kell határoznia Evelyn osztályát. Talán észrevette, hogy az osztályoszlop a név oszloptól balra helyezkedik el, ami meghaladja egy másik hatékony Excel keresőfunkció, a VLOOKUP képességeit.

Valójában a bal oldali keresések végrehajtásának képessége az egyik olyan szempont, ahol az INDEX és a MATCH kombinációja felülmúlja a VLOOKUP-ot.

Megtalálni Evelyn osztálya, használja a következő képletet keresd Evelynt a B2:B11-ben és a lekérni a megfelelő értéket az A2:A11-ből.

=INDEX(A2:A11,MATCH("Evelyn",B2:B11,0))

excel index egyezés 7

Jegyzet: Könnyedén végezhet bal oldali keresést adott értékekhez a segítségével KERESÉS jobbról balra jellemzője Kutools az Excel számára mindössze néhány kattintással. A funkció megvalósításához navigáljon a Kutools fület az Excelben, és kattintson Szuper keresés > KERESÉS jobbról balra a Képlet csoport.

KERESÉS jobbról balra

Ha még nem telepítette a Kutools-t, kattintson ide töltse le és kap egy 30 napos teljes értékű ingyenes próbaverziót!


INDEX és MATCH a kis- és nagybetűk megkülönböztetéséhez

A MATCH függvény eleve nem érzékeny a kis- és nagybetűkre. Ha azonban arra van szüksége, hogy a képlet különbséget tegyen a kis- és nagybetűk között, javíthatja azt a PONTOS funkció. Ha az INDEX képletben a MATCH funkciót az EXACT funkcióval kombinálja, akkor hatékonyan végrehajthat egy kis- és nagybetűk közötti keresést, az alábbiak szerint:

=INDEX(array, MATCH(TRUE, EXACT(lookup_value, lookup_array), 0))
  • sor arra a tartományra utal, ahonnan vissza szeretné adni az értéket.
  • keresési_érték az egyezni kívánt értékre utal, figyelembe véve a karakterek esetét, a lookup_array.
  • lookup_array a cellák azon tartományára utal, amellyel a MATCH-t össze szeretné hasonlítani keresési_érték.

Például tudni JIMMY vizsgapontszáma, használja a következő képletet:

=INDEX(C2:C11,MATCH(TRUE,EXACT("JIMMY",A2:A11),0))

√ Megjegyzés: Ez egy tömbképlet, amellyel be kell írnia Ctrl + műszak + belép, kivéve az Excel 365-ben és az Excel 2021-ben.

excel index egyezés 8

Hogyan működik ez a képlet:
  • Az EXACT függvény összehasonlítja "JIMMY" a listában szereplő értékekkel A2: A11, figyelembe véve a karakterek esetét: Ha a két karakterlánc pontosan egyezik, figyelembe véve a kis- és nagybetűket is, az EXACT eredményt adja vissza TRUE; ellenkező esetben visszatér HAMIS. Ennek eredményeként megkapjuk TRUE és FALSE értékeket tartalmazó tömb.
  • A MATCH függvény ezután lekéri a az első IGAZ érték pozíciója a tömbben, aminek lennie kell 10.
  • Végül az INDEX lekéri az értéket a 10a MATCH által biztosított pozíció a tömbben.

Megjegyzések:

  • Ne felejtse el helyesen megadni a képletet a gomb megnyomásával Ctrl + Shift + Enter, hacsak nem használod Excel 365 or Excel 2021, ebben az esetben egyszerűen nyomja meg belép.
  • A fenti képlet egyetlen listán belül keres C2: C11. Ha több oszlopot és sort tartalmazó tartományon belül szeretne keresni, mondjuk A2: C11, akkor oszlop- és sorszámokat is fel kell ajánlania az INDEX-nek:
  • =INDEX(A2:C11,MATCH(TRUE,EXACT("JIMMY",A2:A11),0),3)
  • Ebben az átdolgozott képletben a MATCH függvényt használjuk a "JIMMY" kifejezésre a tartományban, figyelembe véve a karakterek esetét. A2: A11, és ha találtunk egyezést, lekérjük a megfelelő értéket a 3a tartomány rd oszlopa A2: C11.

INDEX és MATCH, hogy megtalálja a legközelebbi egyezést

Az Excelben olyan helyzetekbe ütközhet, amikor meg kell találnia a legközelebbi vagy legközelebbi egyezést egy adott értékhez egy adatkészleten belül. Ilyen esetekben az INDEX és MATCH funkciók, valamint az ABS és MIN funkciók kombinációja hihetetlenül hasznos lehet.

=INDEX(array, MATCH(MIN(ABS(lookup_array - lookup_value)), ABS(lookup_array - lookup_value),0))
  • sor arra a tartományra utal, ahonnan vissza szeretné adni az értéket.
  • lookup_array arra az értéktartományra utal, amelyhez a legközelebbi egyezést meg szeretné találni keresési_érték.
  • keresési_érték az értékre utal, hogy megtalálja a legközelebbi egyezést.

Például, hogy megtudja amelynek pontszáma a legközelebb van a 85-höz, használja a következő képletet keresse meg a 85-höz legközelebbi pontszámot a C2:C11-ben és a lekérni a megfelelő értéket az A2:A11-ből.

=INDEX(A2:A11,MATCH(MIN(ABS(C2:C11-85)),ABS(C2:C11-85),0))

√ Megjegyzés: Ez egy tömbképlet, amellyel be kell írnia Ctrl + műszak + belép, kivéve az Excel 365-ben és az Excel 2021-ben.

Hogyan működik ez a képlet:
  • ABS (C2:C11-85) kiszámítja a tartomány egyes értékei közötti abszolút különbséget C2: C11 és a 85, ami az abszolút különbségek tömbjét eredményezi.
  • MIN(ABS(C2:C11-85)) megkeresi a minimális értéket az abszolút különbségek tömbjében, amely a 85-höz legközelebbi különbséget jelenti.
  • A MATCH funkció MATCH(MIN(ABS(C2:C11-85)),ABS(C2:C11-85),0) majd megkeresi a minimális abszolút különbség helyét az abszolút különbségek tömbjében, aminek lennie kell 10.
  • Végül az INDEX lekéri a lista pozíciójában lévő értéket A2: A11 amely a legközelebbi pontszámnak felel meg 85 határon belül C2: C11.

Megjegyzések:

  • Ne felejtse el helyesen megadni a képletet a gomb megnyomásával Ctrl + Shift + Enter, hacsak nem használod Excel 365 or Excel 2021, ebben az esetben egyszerűen nyomja meg belép.
  • Döntetlen esetén ez a képlet adja vissza az első mérkőzést.
  • Megtalálni az átlagpontszámhoz legközelebb eső egyezés, cserélje ki 85 a képletben -val ÁTLAG (C2:C11).

INDEX és MATCH, hogy több feltétellel történő keresést alkalmazzon

Ha több feltételnek is megfelel, és két vagy több oszlopban kell keresni, használja a következő képletet. A képlet lehetővé teszi, hogy több feltételre kiterjedő keresést hajtson végre különböző feltételek megadásával a különböző oszlopokban, és segít megtalálni a kívánt értéket, amely megfelel az összes megadott feltételnek.

=INDEX(array, MATCH(1, (lookup_value1=lookup_array1) * (lookup_value2=lookup_array2) * (…), 0))

√ Megjegyzés: Ez egy tömbképlet, amellyel be kell írnia Ctrl + műszak + belép. Ezután egy pár göndör zárójel jelenik meg a képletsorban.

  • sor arra a tartományra utal, ahonnan vissza szeretné adni az értéket.
  • (lookup_value=lookup_array) egyetlen feltételt jelent. Ez a feltétel azt ellenőrzi, hogy egy adott keresési_érték megegyezik az értékekkel lookup_array.

Például, hogy megtalálja a pontszáma az A osztályú Coco, akinek születési dátuma 7, használhatja a következő képletet:

=INDEX(D2:D11,MATCH(1,(G2=A2:A11)*(G3=B2:B11)*(G4=C2:C11),0))

excel index egyezés 9

Megjegyzések:

  • Ebben a képletben kerüljük az értékek keménykódolását, így a cellákban lévő értékek módosításával egyszerűvé válik a különböző információkkal rendelkező pontszámok elérése. G2, G3és G4.
  • A képletet a gomb megnyomásával kell megadnia Ctrl + Shift + Enter kivéve benne Excel 365 or Excel 2021, ahol egyszerűen megnyomhatja belép.
    Ha folyamatosan elfelejti használni Ctrl + Shift + Enter a képlet kitöltéséhez és hibás eredmények eléréséhez használja a következő, kissé bonyolultabb képletet, amellyel egy egyszerű belép kulcs:
    =INDEX(D2:D11,MATCH(1,INDEX((G2=A2:A11)*(G3=B2:B11)*(G4=C2:C11),0,1),0))
  • A képletek bonyolultak lehetnek, és nehéz megjegyezni. A többfeltételes keresés egyszerűsítéséhez a képlet kézi bevitele nélkül fontolja meg a használatát Kutools az Excel számára'S Többfeltételes keresés funkció. A Kutools telepítése után navigáljon a Kutools fület az Excelben, és kattintson Szuper keresés > Többfeltételes keresés a Képlet csoport.

    Többfeltételes keresés

    Ha még nem telepítette a Kutools-t, kattintson ide töltse le és kap egy 30 napos teljes értékű ingyenes próbaverziót!


INDEX és MATCH, hogy több oszlopot is lekérdezhessen

Képzeljen el egy forgatókönyvet, amelyben több adatoszloppal van dolgunk. Az első oszlop kulcsként működik a többi oszlopban lévő adatok besorolásához. Egy adott bejegyzés kategóriájának vagy besorolásának meghatározásához keresést kell végrehajtania az adatoszlopok között, és hozzá kell rendelnie a referenciaoszlopban található kulcshoz.

Például az alábbi táblázatban hogyan párosíthatjuk Shawn tanulót a megfelelő osztályával az INDEX és a MATCH használatával? Nos, egy képlettel elérheti, de a képlet meglehetősen kiterjedt, és nehéz lehet megérteni, nem beszélve az emlékezetről és a gépelésről.

=IFERROR(INDEX($A$2:$A$4,MATCH(IF(SUM(MMULT(--($B$2:$E$4=G2),TRANSPOSE(COLUMN($B$2:$E$4)^0)))>0,1,-1),MMULT(--($B$2:$E$4=G2),TRANSPOSE(COLUMN($B$2:$E$4)^0))^0,0)), "")

Ahol Kutools az Excel számára's Index és egyezés több oszlopon jól jön a funkció. Leegyszerűsíti a folyamatot, így gyors és egyszerű az egyes bejegyzések és a megfelelő kategóriák párosítása. Egyszerűen feloldhatja ezt a hatékony eszközt, és könnyedén összehozhatja Shawnt az osztályával töltse le és telepítse a Kutools for Excel bővítményt, majd tegye a következőket:

  1. Válassza ki azt a célcellát, ahol meg szeretné jeleníteni a megfelelő osztályt.
  2. A Kutools fülre kattintva Formula Segítő > Keresés és referencia > Index és egyezés több oszlopon.
  3. excel index egyezés 11
  4. A felugró párbeszédpanelen tegye a következőket:
    1. Kattintson az 1 Excel index egyezési ikon gomb mellett Look_col a visszaadni kívánt kulcsinformációkat, azaz az osztályneveket tartalmazó oszlop kiválasztásához. (Itt csak egy oszlopot választhat ki.)
    2. Kattintson a 2 Excel index egyezési ikon gomb mellett Table_rng a cellák kiválasztásához, hogy megfeleljenek a kiválasztott értékeknek Look_col, azaz a tanulók nevei.
    3. Kattintson a 3 Excel index egyezési ikon gomb mellett Keresési_érték jelölje ki azt a cellát, amely annak a diáknak a nevét tartalmazza, akit az osztályával egyeztetni szeretne, jelen esetben Shawn.
    4. Kattints OK.
    5. excel index egyezés 12

Eredmény

A Kutools automatikusan létrehozta a képletet, és Shawn osztályneve azonnal megjelenik a célcellában.

Jegyzet: Kipróbálni a Index és egyezés több oszlopon funkciót, telepítenie kell a Kutools for Excel alkalmazást a számítógépére. Ha még nem telepítette, ne várjon --- Töltse le és telepítse most a 30 napos ingyenes próbaidőszakért, korlátozások nélkül. Tedd okosabbá az Excel működését még ma!


INDEX és MATCH az első nem üres érték kereséséhez

Ha egy oszlopból vagy egy sorból szeretné lekérni az első nem üres értéket, figyelmen kívül hagyva a hibákat, használhat egy INDEX és MATCH függvényeken alapuló képletet. Ha azonban nem szeretné figyelmen kívül hagyni a tartományból származó hibákat, adja hozzá az ISBLANK függvényt.

  • Az első nem üres érték lekérése egy oszlopban vagy sorban a hibák figyelmen kívül hagyásával:
  • =INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))
  • Az első nem üres érték lekérése egy oszlopban vagy sorban, beleértve a hibákat:
  • =INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

Megjegyzések:


INDEX és MATCH az első számérték kereséséhez

Ha egy oszlopból vagy egy sorból szeretné lekérni az első számértéket, használja az INDEX, MATCH és ISNUMBER függvényeken alapuló képletet.

=INDEX(B4:B15,MATCH(TRUE,ISNUMBER(B4:B15),0))

Megjegyzések:


INDEX és MATCH a MAX vagy MIN társítások kereséséhez

Ha egy tartományon belüli maximális vagy minimális értékhez tartozó értéket kell lekérnie, használhatja a MAX vagy MIN függvényt az INDEX és MATCH függvényekkel együtt.

  • INDEX és MATCH a maximális értékhez tartozó érték lekéréséhez:
  • =INDEX(array, MATCH(MAX(lookup_array), lookup_array, 0))
  • INDEX és MATCH a minimális értékhez tartozó érték lekéréséhez:
  • =INDEX(array, MATCH(MIN(lookup_array), lookup_array, 0))
  • A fenti képletekben két érv található:
    • sor arra a tartományra utal, ahonnan a kapcsolódó információkat vissza kívánja adni.
    • lookup_array a vizsgálandó vagy meghatározott kritériumok, azaz a maximális vagy minimális értékek alapján keresendő értékek halmazát jelenti.

Például, ha meg akarja határozni akinek a legmagasabb pontszáma van, használja a következő képletet:

=INDEX(A2:A11,MATCH(MAX(C2:C11),C2:C11,0))

Hogyan működik ez a képlet:
  • MAX(C2:C11) a tartomány legmagasabb értékét keresi C2: C11, Amely 96.
  • A MATCH függvény ezután megkeresi a legmagasabb érték pozícióját a tömbben C2: C11, aminek kell lennie 1.
  • Végül az INDEX lekéri a 1st érték a listában A2: A11.

Megjegyzések:

  • Egynél több maximális vagy minimális érték esetén, amint az a fenti példában látható, ahol két tanuló ugyanazt a legmagasabb pontszámot érte el, ez a képlet az első egyezést adja vissza.
  • A legalacsonyabb pontszám meghatározásához használja a következő képletet:
    =INDEX(A2:A11,MATCH(MIN(C2:C11),C2:C11,0))

Tipp: Szabja személyre #N/A hibaüzeneteit

Amikor az Excel INDEX és MATCH függvényeivel dolgozik, előfordulhat, hogy #N/A hibaüzenetet kap, ha nincs egyező eredmény. Például az alábbi táblázatban egy Samantha nevű tanuló pontszámának megkeresésekor #N/A hibaüzenet jelenik meg, mivel a lány nincs jelen az adatkészletben.

excel index egyezés 15

A táblázatok felhasználóbarátabbá tétele érdekében testreszabhatja ezt a hibaüzenetet úgy, hogy becsomagolja az INDEX MATCH képletet az IFNA függvénybe:

=IFNA(INDEX(C2:C11,MATCH(F2,A2:A11,0)),"Not found")

excel index egyezés 16

Megjegyzések:

  • Cserélésével testreszabhatja a hibaüzeneteket "Nem található" tetszőleges szöveggel.
  • Ha az összes hibát szeretné kezelni, nem csak a #N/A hibát, fontolja meg a IFROROR funkció helyett IFNA:
    =IFERROR(INDEX(C2:C11,MATCH(F2,A2:A11,0)),"Not found")

    Vegye figyelembe, hogy nem tanácsos minden hibát elhallgatni, mert ezek figyelmeztetésként szolgálnak a képletek lehetséges problémáira.

Fent található az Excel INDEX és MATCH függvényeivel kapcsolatos összes releváns tartalom. Remélem, hasznosnak találja az oktatóanyagot. Ha további Excel-tippeket és trükköket szeretne felfedezni, kérem kattintson ide több ezer oktatóanyagból álló kiterjedt gyűjteményünk eléréséhez.

Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations