Hogyan lehet lekérni a feladó e-mail címét egy vagy több e-mailből az Outlookban?

Próbálta már kivonni az e-mail címet egy vagy több fogadott e-mail „Feladó” mezőjéből az Outlook programban? Ez a cikk egy VBA-kódot tartalmaz, amely segít a feladat kezelésében.

A feladó e-mail címének lekérése egy vagy több e-mailből az Outlookban

Kérjük, futtassa a következő VBA-kódot az e-mail cím kinyeréséhez egy vagy több fogadott e-mail „Feladó” mezőjéből az Outlook programban.

1. Nyisson meg egy e-mail mappát, válassza ki azt az e-mail üzenetet, amelyből a feladó e-mail címét szeretné megkapni. megnyomni a más + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

tippek: Több e-mail kiválasztásához tartsa lenyomva a gombot Ctrl gombot, majd egyenként válassza ki az e-maileket.

2. Ban,-ben Microsoft Visual Basic for Applications ablakban kattintson betétlap > Modulok, majd másolja a következő VBA-kódot a Modul (kód) ablakba.

VBA-kód: a feladó e-mail címének kibontása egy vagy több e-mailből az Outlookban

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. kettyenés Eszközök > Referenciák, majd ellenőrizze a Microsoft Scripting Runtime doboz a Referenciák – Projekt1 párbeszédablak.

4. megnyomni a F5 gombot a kód futtatásához. Aztán a Kutools az Outlook számára párbeszédpanel jelenik meg, amely felsorolja a kiválasztott e-mailek összes feladójának e-mail címét.

tippek:

Ha txt fájlba kell exportálnia a címlistát, kattintson a Igen gombot.

Vagy kattintson a Nem gombot a folyamat befejezéséhez.

5. Miután a gombra kattintott Igen gomb, a Tallózás a mappába párbeszédpanel jelenik meg. Kérjük, válasszon mappát a fájl mentéséhez, és kattintson a gombra OK gombot.

6. Végül a Kutools az Outlook számára párbeszédpanel jelenik meg, amely közli az exportált fájl elérési útját. Kattintson OK bezárni.

7. Lépjen abba a mappába, ahová az exportált fájlt menti, és nyissa meg a .txt nevű fájlt Székhely a kiválasztott e-mailek feladóinak e-mail címeinek megtekintéséhez.