Hogyan exportálhatunk e-mail címeket adott domain alapján az Outlookban?

Ha egy adott tartományhoz tartozó e-mail címeket szeretne exportálni az Outlook összes névjegyéből, kérjük, olvassa el ezt az oktatóanyagot, amely segít egy VBA-kód alkalmazásában egy adott tartomány összes e-mail címének szöveges fájlba történő kibontásához, az alábbi képernyőképen látható módon. .

Exportáljon e-mail címeket egy adott tartomány alapján az Outlook programban VBA-kóddal

Ha egy adott domainhez tartozó összes e-mail címet ki szeretne bontani az összes névjegyből, kövesse az alábbi lépéseket:

1. Hozzon létre egy új szövegfájlt, és adjon neki nevet, lásd a képernyőképet:

2. Tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

3. Ezután kattints a gombra betétlap > Modulok, és illessze be a következő kódot a Modul ablakba.

VBA-kód: Exportáljon e-mail címeket adott domain alapján

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

Megjegyzések: A fenti kódban módosítsa a fájl elérési útját "C:\Users\skyyang\Desktop\Email Addresses adott domain.txt fájllal" a sajátodhoz.

4. És akkor nyomja meg F5 kulcs a kód futtatásához. Megjelenik egy prompt mező, írja be az e-mail domaint, amely alapján exportálni szeretné az e-mail címeket, lásd a képernyőképet:

5. Ezután kattints a gombra OK gombot, és az adott tartományban található összes e-mail cím egyszerre kicsomagolásra kerül a szövegfájlba, lásd a képernyőképet: