Hogyan lehet megtartani a kategóriát, miközben e-maileket válaszol vagy továbbít az Outlook programban?

Normális esetben, amikor válaszol vagy továbbít egy általam kategorizált e-mailt, a kategória automatikusan törlődik az elküldött e-mailről. Ha válaszolni vagy továbbítani szeretné a kimenő e-mailek kategóriáját, ez a cikk bemutatja a kezelésének módját.

Tartsa a kategóriát, miközben VBA kóddal válaszol vagy továbbít e-mailt

Tartsa a kategóriát, miközben VBA kóddal válaszol vagy továbbít e-mailt

1. Tartsa lenyomva a ALT + F11 billentyűk megnyitásához Microsoft Visual Basic for Applications ablak.

2. Az Microsoft Visual Basic for Applications ablakban kattintson duplán ThisOutlookSession tól Project1 (VbaProject.OTM) ablaktáblán nyissa meg a módot, majd másolja és illessze be a következő kódot az üres modulba.

VBA kód: Kategória megőrzése e-mail válaszadás vagy továbbítás közben:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

doc kategória válasz megőrzése 1

3. Ezután mentse és zárja be ezt a kódablakot, zárja be és indítsa újra az Outlook programot. Most, amikor kategóriájú e-mailt válaszol vagy továbbít, a kategória a kimenő üzenetben marad Elküldött elemek, lásd a képernyőképet:

doc kategória válasz megőrzése 2